home *** CD-ROM | disk | FTP | other *** search
/ AmigActive 26 / AACD 26.iso / AACD / Programming / ace_gpl_release / src / lib / asm / turtle.s < prev    next >
Encoding:
Text File  |  1998-10-04  |  5.6 KB  |  331 lines
  1. ;
  2. ; turtle.lib -- an ACE linked library module: turtle graphics functions.
  3. ; Copyright (C) 1998 David Benn
  4. ; 
  5. ; This program is free software; you can redistribute it and/or
  6. ; modify it under the terms of the GNU General Public License
  7. ; as published by the Free Software Foundation; either version 2
  8. ; of the License, or (at your option) any later version.
  9. ;
  10. ; This program is distributed in the hope that it will be useful,
  11. ; but WITHOUT ANY WARRANTY; without even the implied warranty of
  12. ; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13. ; GNU General Public License for more details.
  14. ;
  15. ; You should have received a copy of the GNU General Public License
  16. ; along with this program; if not, write to the Free Software
  17. ; Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA.
  18. ;
  19. ; Author: David J Benn
  20. ;   Date: 3rd July 1992,
  21. ;      5th December 1992,
  22. ;      14th February 1993,
  23. ;      1st March 1993,
  24. ;      19th March 1994
  25. ;
  26.  
  27.     ; turtle graphics routines, 
  28.     ; functions & variables
  29.     xdef    _back
  30.     xdef    _forward
  31.     xdef    _heading
  32.     xdef    _home
  33.     xdef    _pendown
  34.     xdef    _penup
  35.     xdef    _setheading
  36.     xdef    _setxy
  37.     xdef    _turn
  38.     xdef    _turnleft
  39.     xdef    _turnright
  40.     xdef    _xcor
  41.     xdef    _ycor
  42.  
  43.     ; external ref's
  44.     xref    _tg_initx
  45.     xref    _tg_inity
  46.     xref    _tg_xy_ratio
  47.     xref    _radconv
  48.  
  49.     xref    _tg_degs
  50.     xref    _tg_tx
  51.     xref    _tg_ty
  52.     xref    _tg_pen
  53.     xref    _tg_distance
  54.     xref    _tg_theta
  55.     xref    _tg_temp
  56.     xref    _tg_x
  57.     xref    _tg_y
  58.     
  59.     xref    _MathBase
  60.     xref    _MathTransBase
  61.     xref    _GfxBase
  62.     xref    _RPort
  63.     xref    _LVODraw
  64.     xref    _LVOMove
  65.     xref    _LVOSPFlt
  66.     xref    _LVOSPFix
  67.     xref    _LVOSPMul
  68.     xref    _LVOSPDiv
  69.     xref    _LVOSPSin
  70.     xref    _LVOSPCos
  71.  
  72.     SECTION turtle_code,CODE
  73.  
  74. ; *** TURTLE GRAPHICS ROUTINES ***
  75.  
  76. ;
  77. ; moveturtle - primitive used by forward and back.
  78. ;         - expects distance in d0 (ffp) 
  79. ;           and direction boolean in d1 (0=back, 1=forward).
  80. ;
  81. ;         - d2 = angle (temporary store)
  82. ;
  83. _moveturtle:
  84.     ; save d0 
  85.     move.l    d0,_tg_distance
  86.  
  87.     cmpi.w    #1,d1
  88.     beq.s    _forwardcalc    
  89.     
  90.     ; reverse
  91.     move.w    _tg_degs,d2
  92.     add.w    #180,d2
  93.     ext.l    d2
  94.     divs    #360,d2
  95.     swap    d2        ; angle = (degs+180) % 360
  96.     
  97.     ext.l    d2
  98.     move.l    _MathBase,a6
  99.     move.l    d2,d0
  100.     jsr    _LVOSPFlt(a6)    ; angle = (float)angle
  101.  
  102.     move.l    _radconv,d1
  103.     jsr    _LVOSPDiv(a6)    ; theta = angle/radconv
  104.  
  105.     move.l    d0,_tg_theta
  106.  
  107.     bra.s    _calcxy        
  108.     
  109. _forwardcalc:    
  110.     ; forward    
  111.     move.l    _MathBase,a6
  112.     move.w    _tg_degs,d0
  113.     ext.l    d0
  114.     jsr    _LVOSPFlt(a6)    ; degs = (float)degs
  115.  
  116.     move.l    _radconv,d1
  117.     jsr    _LVOSPDiv(a6)    ; theta = degs/radconv
  118.     
  119.     move.l    d0,_tg_theta
  120.  
  121.     move.l    d0,d1
  122.  
  123. _calcxy:
  124.     ; calculate x
  125.     move.l    _tg_xy_ratio,d0    ; X:Y ratio = 2.25 (assumes hi-res & is approx.)
  126.     move.l    _tg_distance,d1
  127.     jsr    _LVOSPMul(a6)    
  128.     move.l    d0,_tg_temp
  129.     
  130.     move.l    _MathTransBase,a6
  131.     move.l    _tg_theta,d0
  132.     jsr    _LVOSPCos(a6)
  133.     
  134.     move.l    _MathBase,a6
  135.     move.l    _tg_temp,d1
  136.     jsr    _LVOSPMul(a6)
  137.     
  138.     jsr    _LVOSPFix(a6)    ; x = (int)(2.25*dist*cos(theta))
  139.  
  140.     move.w    d0,_tg_x
  141.  
  142.     ; calculate y
  143.     move.l    _MathTransBase,a6
  144.     move.l    _tg_theta,d0
  145.     jsr    _LVOSPSin(a6)
  146.     
  147.     move.l    _MathBase,a6
  148.     move.l    _tg_distance,d1
  149.     jsr    _LVOSPMul(a6)
  150.     
  151.     jsr    _LVOSPFix(a6)    ; y = (int)(dist*sin(theta))
  152.  
  153.     move.w    d0,_tg_y
  154.  
  155.     ; next x and y are offset from tx and ty
  156.     move.w    _tg_tx,d0
  157.     move.w    _tg_x,d1
  158.     add.w    d0,d1    
  159.     move.w    d1,_tg_x    ; x = tx+x
  160.  
  161.     move.w    _tg_ty,d0
  162.     move.w    _tg_y,d1
  163.     add.w    d0,d1    
  164.     move.w    d1,_tg_y    ; y = ty+y
  165.  
  166.     ; if pen is up -> don't draw
  167.     cmpi.b    #1,_tg_pen
  168.     beq.s    _draw_to_new_pos
  169.  
  170.     ; pen up -> don't draw, just move to x,y
  171.     move.l    _GfxBase,a6
  172.     move.l    _RPort,a1
  173.     move.w    _tg_x,d0
  174.     move.w    _tg_y,d1
  175.     jsr    _LVOMove(a6)
  176.     bra.s    _setnewtx_ty
  177.  
  178. _draw_to_new_pos:
  179.     ; pen down -> draw a line!
  180.     move.l    _GfxBase,a6
  181.     move.l    _RPort,a1
  182.     move.w    _tg_x,d0
  183.     move.w    _tg_y,d1
  184.     jsr    _LVODraw(a6)
  185.         
  186. _setnewtx_ty:
  187.     move.w    _tg_x,_tg_tx
  188.     move.w    _tg_y,_tg_ty
  189.     
  190.     rts
  191.         
  192. ;
  193. ; rotate - primitive used by setheading, turn, turnleft and turnright.
  194. ;     - expects degrees in d0 (SIGNED short integer).
  195. ;
  196. _rotate:
  197.     ext.l    d0
  198.     divs    #360,d0        ; MUST be signed division
  199.     swap    d0        ; degs = d0 % 360
  200.  
  201.         cmpi.w    #0,d0
  202.     bge.s    _storeheading
  203.     add.w    #360,d0        ; if d0 < 0 -> d0=360+d0
  204. _storeheading:
  205.     move.w    d0,_tg_degs    
  206.     rts
  207.  
  208. ;
  209. ; back - move turtle back by value in d0 (ffp).
  210. ;
  211. _back:
  212.     move.w    #0,d1
  213.     jsr    _moveturtle
  214.     rts
  215.  
  216. ;
  217. ; forward - move turtle forward by value in d0 (ffp).
  218. ;
  219. _forward:
  220.     move.w    #1,d1
  221.     jsr    _moveturtle
  222.     rts
  223.  
  224. ;
  225. ; heading - return current turtle heading in d0.
  226. ;
  227. _heading:
  228.     move.w    _tg_degs,d0
  229.     rts
  230.  
  231. ;
  232. ; home - move turtle to home position, drawing a line if pen down. 
  233. ;      - a special case of setxy.
  234. ;
  235. _home:
  236.     move.w    _tg_initx,d0
  237.     move.w    _tg_inity,d1
  238.     jsr    _setxy    
  239.     rts
  240.     
  241. ;
  242. ; pendown - put the turtle's pen down.
  243. ;
  244. _pendown:
  245.     move.b    #1,_tg_pen
  246.     rts
  247.  
  248. ;
  249. ; penup - lift the turtle's pen up.
  250. ;
  251. _penup:
  252.     move.b    #0,_tg_pen
  253.     rts
  254.  
  255. ;
  256. ; setheading - change turtle's heading to value in d0 (degrees).
  257. ;    
  258. _setheading:
  259.     jsr    _rotate
  260.     rts
  261.  
  262. ;
  263. ; setxy - change the drawing coordinates to d0,d1.
  264. ;    - expects x in d0 and y in d1.
  265. ;
  266. _setxy:
  267.     move.w    d0,_tg_tx
  268.     move.w    d1,_tg_ty
  269.  
  270.     cmpi.b    #1,_tg_pen
  271.     beq.s    _drawpath    ; if pen down -> draw!
  272.  
  273.     ; pen up -> just move to x,y
  274.     move.l    _GfxBase,a6
  275.     move.l    _RPort,a1
  276. ;    move.w    _tg_tx,d0
  277. ;    move.w    _tg_ty,d1
  278.     jsr    _LVOMove(a6)
  279.     bra    _exitsetxy
  280.  
  281. _drawpath:
  282.     ; pen down -> draw line
  283.     move.l    _GfxBase,a6
  284.     move.l    _RPort,a1
  285. ;    move.w    _tg_tx,d0
  286. ;    move.w    _tg_ty,d1
  287.     jsr    _LVODraw(a6)
  288.     
  289. _exitsetxy:    
  290.     rts
  291.  
  292. ;
  293. ; turn - rotate turtle by d0 degrees from current heading. 
  294. ;
  295. _turn:
  296.     add.w    _tg_degs,d0
  297.     jsr    _rotate
  298.     rts
  299. ;
  300. ; turnleft - rotate turtle d0 degrees to the left from current heading. 
  301. ;
  302. _turnleft:
  303.     move.w    _tg_degs,d1
  304.     sub.w    d0,d1
  305.     move.w    d1,d0
  306.     jsr    _rotate
  307.     rts
  308. ;
  309. ; turnright - rotate turtle d0 degrees to the right from current heading. 
  310. ;
  311. _turnright:
  312.     add.w    _tg_degs,d0
  313.     jsr    _rotate
  314.     rts
  315.  
  316. ;
  317. ; xcor - returns the turtle's x-coordinate in d0.
  318. ;
  319. _xcor:
  320.     move.w    _tg_tx,d0
  321.     rts
  322.  
  323. ;
  324. ; ycor - returns the turtle's y-coordinate in d0.
  325. ;
  326. _ycor:
  327.     move.w    _tg_ty,d0
  328.     rts
  329.  
  330.     END
  331.